arch-pkgs/opentyrian/PKGBUILD

61 lines
1.9 KiB
Bash

# Maintainer: Patrick Northon <northon_patrick3@yahoo.ca>
# Contributor: carstene1ns <url/mail: arch carsten-teibes de>
# Contributor: Jan Alexander Steffens (heftig) <jan.steffens@gmail.com>
pkgname=opentyrian
pkgver=2.1.20220318
pkgrel=1
pkgdesc='Open Source port of the classic DOS shoot-em-up Tyrian'
url="https://github.com/opentyrian/opentyrian"
arch=('x86_64')
license=('GPL2')
depends=('sdl2' 'sdl2_net' 'hicolor-icon-theme')
makedepends=('git')
_commit='8f205e6b12cb9c34905fa960416b6f661bf38ac3'
source=(
"$pkgname::git+https://github.com/opentyrian/opentyrian.git#commit=$_commit"
"$pkgname-assets.zip::https://camanis.net/tyrian/tyrian21.zip"
'update-paths.patch'
)
sha512sums=('SKIP'
'639aa773778386c14ce508feb4729512d00f80182a3bb0fe8bba4ee38bce91da1867ca93f1a7e5e30ff127da077eed275d8dd6ba82042b627b84f1606e2d6bce'
'7059d2c5a19191e1cf24abbf764adbd0fa81d8b529e1f5839a330b15a3023af78763f90de3f559fb980e30081110b6b9c1b1097823a58caa3e0ca00b2a20ce6c')
b2sums=('SKIP'
'6bef66fbc34a4d2d865fe7088a6942a29348153d0d10347860952a152b882fd9eef1748fbfa9fd32d030593d2f8c21e1cd227dd6ca540488ba5093b95a95fb33'
'7535e7ee5773a4e8de6bd51110931aa81b9abaa11f215c846cc914bebf352984a317ae5f31f47ed36cdd4e5a4ec286dabe0b3a31985b50c12f1859568924fe3c')
pkgver() {
cd "$pkgname"
git describe --tags | sed 's/^v//'
}
prepare() {
cd "$pkgname"
patch -p1 -i ../update-paths.patch
}
build() {
make prefix=/usr all -C "$pkgname"
}
package() {
cd "$pkgname"
make DESTDIR="$pkgdir" prefix=/usr install
# desktop file & icons
install -vDm644 -t "$pkgdir/usr/share/applications" linux/opentyrian.desktop
for _x in 22 24 32 48 128; do
install -vDm644 "linux/icons/tyrian-$_x.png" \
"$pkgdir/usr/share/icons/hicolor/${_x}x${_x}/apps/$pkgname.png"
done
# assets
cd "$srcdir/tyrian21"
install -vDm644 -t "$pkgdir/usr/share/$pkgname" \
*.dat *.lvl *.shp *.snd demo.* music.mus \
tyrend.anm tyrian.{cdt,hdt,pic} tshp2.pcx
}