arch-pkgs/zsh-grawlinson/PKGBUILD

39 lines
1.1 KiB
Bash

# Maintainer: George Rawlinson <george@rawlinson.net.nz>
pkgname=zsh-grawlinson
pkgver=0.1.3
pkgrel=1
pkgdesc="grawlinson's opinionated zsh framework"
arch=('any')
url="https://github.com/grawlinson/zsh-grawlinson"
license=('MIT')
depends=('zsh' 'zsh-completions' 'zsh-prompt-ys')
backup=(
'etc/zsh/zshenv'
'etc/zsh/zshrc'
)
options=('!emptydirs')
source=(
"$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz"
"$pkgname-$pkgver.tar.gz.asc::$url/releases/download/$pkgver/$pkgver.tar.gz.asc"
)
b2sums=('406dd4d602cb769deb7de8f83f28599fde19f102a7fae137807f00c973bc3fe57302915666cd83417981407df9f27f1fadd1245819a5007d4bacb15f7fc57b6a'
'SKIP')
validpgpkeys=('034D823DA2055BEE6A6BF0BB25EA6900D9EA5EBC') # George Rawlinson <george@rawlinson.net.nz>
package() {
cd "$pkgname-$pkgver"
# framework
install -vd "$pkgdir/usr/share/$pkgname/prompts"
for folder in completions functions plugins source; do
cp -vr "$folder" "$pkgdir/usr/share/$pkgname"
done
# global zsh config
install -vDm644 -t "$pkgdir/etc/zsh" zsh{rc,env}
# LICENSE
install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}