46 lines
1.4 KiB
Bash
46 lines
1.4 KiB
Bash
# Maintainer: Simon Legner <Simon.Legner@gmail.com>
|
|
# Contributor: George Rawlinson <george@rawlinson.net.nz>
|
|
|
|
pkgname=rollup
|
|
pkgver=2.56.3
|
|
pkgrel=1
|
|
pkgdesc="Next-generation ES6 module bundler"
|
|
arch=(any)
|
|
url="https://rollupjs.org/"
|
|
license=('MIT' 'ISC')
|
|
depends=('nodejs')
|
|
makedepends=('npm' 'jq')
|
|
source=("$pkgname-$pkgver.tar.gz::https://registry.npmjs.org/$pkgname/-/$pkgname-$pkgver.tgz")
|
|
noextract=("$pkgname-$pkgver.tar.gz")
|
|
b2sums=('52062640f92352713ce4b95a84e6157939ef089a77ece0d0edd0ae56f500ece50102fcdab06fa71782acfc89f9b835f1645616fcc4a0ed4353b16f6076abebfe')
|
|
|
|
package() {
|
|
local NPM_FLAGS=(--no-audit --no-fund --no-update-notifier)
|
|
|
|
npm install \
|
|
--global \
|
|
--prefix "$pkgdir/usr" \
|
|
--cache "$srcdir/npm-cache" \
|
|
"${NPM_FLAGS[@]}" \
|
|
"$pkgname-$pkgver.tar.gz"
|
|
|
|
# install licenses
|
|
install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" \
|
|
"$pkgdir/usr/lib/node_modules/rollup/LICENSE.md"
|
|
|
|
# install documentation
|
|
install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" \
|
|
"$pkgdir/usr/lib/node_modules/rollup/"{CHANGELOG,README}.md
|
|
|
|
# remove references to ${src,pkg}dir
|
|
local tmppackage="$(mktemp)"
|
|
local pkgjson="$pkgdir/usr/lib/node_modules/$pkgname/package.json"
|
|
jq '.|=with_entries(select(.key|test("_.+")|not))' "$pkgjson" > "$tmppackage"
|
|
mv "$tmppackage" "$pkgjson"
|
|
chmod 644 "$pkgjson"
|
|
|
|
# npm gives ownership of ALL FILES to build user
|
|
# https://bugs.archlinux.org/task/63396
|
|
chown -R root:root "$pkgdir"
|
|
}
|