46 lines
1.6 KiB
Bash
46 lines
1.6 KiB
Bash
# Maintainer: Simon Legner <Simon.Legner@gmail.com>
|
|
# Contributor: George Rawlinson <george@rawlinson.net.nz>
|
|
|
|
pkgname=rollup
|
|
pkgver=2.61.0
|
|
pkgrel=1
|
|
pkgdesc="Next-generation ES6 module bundler"
|
|
arch=(any)
|
|
url="https://rollupjs.org/"
|
|
license=('MIT' 'ISC')
|
|
depends=('nodejs')
|
|
makedepends=('npm' 'jq')
|
|
source=("$pkgname-$pkgver.tar.gz::https://registry.npmjs.org/$pkgname/-/$pkgname-$pkgver.tgz")
|
|
noextract=("$pkgname-$pkgver.tar.gz")
|
|
sha512sums=('b5e43e4f599461bcaf1b251abc2a1d8b203d843e03c70619270affa9e8591a1b35678f6fb26cde94c558331194e1984644ac583eea47bb3e72ce6ff08fb56958')
|
|
b2sums=('65ff49bcac155951cab6ffa0850ec6d201030a51b3dc051ed308ba16d7f8bb2b778b06fb09ea04bddefbb4c0025c4e46a766800709c25d56711a587bc05a1d3a')
|
|
|
|
package() {
|
|
local NPM_FLAGS=(--no-audit --no-fund --no-update-notifier)
|
|
|
|
npm install \
|
|
--global \
|
|
--prefix "$pkgdir/usr" \
|
|
--cache "$srcdir/npm-cache" \
|
|
"${NPM_FLAGS[@]}" \
|
|
"$pkgname-$pkgver.tar.gz"
|
|
|
|
# install licenses
|
|
install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" \
|
|
"$pkgdir/usr/lib/node_modules/rollup/LICENSE.md"
|
|
|
|
# install documentation
|
|
install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" \
|
|
"$pkgdir/usr/lib/node_modules/rollup/"{CHANGELOG,README}.md
|
|
|
|
# remove references to ${src,pkg}dir
|
|
local tmppackage="$(mktemp)"
|
|
local pkgjson="$pkgdir/usr/lib/node_modules/$pkgname/package.json"
|
|
jq '.|=with_entries(select(.key|test("_.+")|not))' "$pkgjson" > "$tmppackage"
|
|
mv "$tmppackage" "$pkgjson"
|
|
chmod 644 "$pkgjson"
|
|
|
|
# npm gives ownership of ALL FILES to build user
|
|
# https://bugs.archlinux.org/task/63396
|
|
chown -R root:root "$pkgdir"
|
|
}
|