46 lines
1.6 KiB
Bash
46 lines
1.6 KiB
Bash
# Maintainer: Simon Legner <Simon.Legner@gmail.com>
|
|
# Contributor: George Rawlinson <george@rawlinson.net.nz>
|
|
|
|
pkgname=rollup
|
|
pkgver=2.61.1
|
|
pkgrel=1
|
|
pkgdesc="Next-generation ES6 module bundler"
|
|
arch=(any)
|
|
url="https://rollupjs.org/"
|
|
license=('MIT' 'ISC')
|
|
depends=('nodejs')
|
|
makedepends=('npm' 'jq')
|
|
source=("$pkgname-$pkgver.tar.gz::https://registry.npmjs.org/$pkgname/-/$pkgname-$pkgver.tgz")
|
|
noextract=("$pkgname-$pkgver.tar.gz")
|
|
sha512sums=('05b4d7944bc1f1df9715b2bfec4e5da08711b7158f462aabd1e6f9bd0d3eda968c334e187b83d96399c739079fda2c76e25fcbd12a4b779870707d794073ddbc')
|
|
b2sums=('8f9396c4a64f433bbba98728473012b96ef72581f47f55c921ed60f9b5ff7c1b4cfbe05d3ed040251103c19f925f92e12d46f63fd326c67f3518aa4b177b786c')
|
|
|
|
package() {
|
|
local NPM_FLAGS=(--no-audit --no-fund --no-update-notifier)
|
|
|
|
npm install \
|
|
--global \
|
|
--prefix "$pkgdir/usr" \
|
|
--cache "$srcdir/npm-cache" \
|
|
"${NPM_FLAGS[@]}" \
|
|
"$pkgname-$pkgver.tar.gz"
|
|
|
|
# install licenses
|
|
install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" \
|
|
"$pkgdir/usr/lib/node_modules/rollup/LICENSE.md"
|
|
|
|
# install documentation
|
|
install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" \
|
|
"$pkgdir/usr/lib/node_modules/rollup/"{CHANGELOG,README}.md
|
|
|
|
# remove references to ${src,pkg}dir
|
|
local tmppackage="$(mktemp)"
|
|
local pkgjson="$pkgdir/usr/lib/node_modules/$pkgname/package.json"
|
|
jq '.|=with_entries(select(.key|test("_.+")|not))' "$pkgjson" > "$tmppackage"
|
|
mv "$tmppackage" "$pkgjson"
|
|
chmod 644 "$pkgjson"
|
|
|
|
# npm gives ownership of ALL FILES to build user
|
|
# https://bugs.archlinux.org/task/63396
|
|
chown -R root:root "$pkgdir"
|
|
}
|