47 lines
1.6 KiB
Bash
47 lines
1.6 KiB
Bash
# Maintainer: Simon Legner <Simon.Legner@gmail.com>
|
|
# Contributor: George Rawlinson <george@rawlinson.net.nz>
|
|
|
|
pkgname=rollup
|
|
pkgver=2.59.0
|
|
pkgrel=1
|
|
pkgdesc="Next-generation ES6 module bundler"
|
|
arch=(any)
|
|
url="https://rollupjs.org/"
|
|
license=('MIT' 'ISC')
|
|
depends=('nodejs')
|
|
makedepends=('npm' 'jq')
|
|
source=("$pkgname-$pkgver.tar.gz::https://registry.npmjs.org/$pkgname/-/$pkgname-$pkgver.tgz")
|
|
noextract=("$pkgname-$pkgver.tar.gz")
|
|
sha512sums=('97bb3dd09421090e89c998ca828ecbab574a8764716ad38cf89afa6bd17b59b4bd5a029ba1cc9449e2e6665f1ebc0b1eef2f7a01ef7c2f69357013b0583f271f')
|
|
b2sums=('a4e66852874f901302fde00c146d771a4e4d87611b86004758077e0a0f268df560e3e935a4196d9e3f3c6e62a6666af466ff506f9f92b68543de06979caf6b11')
|
|
|
|
package() {
|
|
local NPM_FLAGS=(--no-audit --no-fund --no-update-notifier)
|
|
|
|
npm install \
|
|
--global \
|
|
--prefix "$pkgdir/usr" \
|
|
--cache "$srcdir/npm-cache" \
|
|
"${NPM_FLAGS[@]}" \
|
|
"$pkgname-$pkgver.tar.gz"
|
|
|
|
# install licenses
|
|
install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" \
|
|
"$pkgdir/usr/lib/node_modules/rollup/LICENSE.md"
|
|
|
|
# install documentation
|
|
install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" \
|
|
"$pkgdir/usr/lib/node_modules/rollup/"{CHANGELOG,README}.md
|
|
|
|
# remove references to ${src,pkg}dir
|
|
local tmppackage="$(mktemp)"
|
|
local pkgjson="$pkgdir/usr/lib/node_modules/$pkgname/package.json"
|
|
jq '.|=with_entries(select(.key|test("_.+")|not))' "$pkgjson" > "$tmppackage"
|
|
mv "$tmppackage" "$pkgjson"
|
|
chmod 644 "$pkgjson"
|
|
|
|
# npm gives ownership of ALL FILES to build user
|
|
# https://bugs.archlinux.org/task/63396
|
|
chown -R root:root "$pkgdir"
|
|
}
|