You can not select more than 25 topics
Topics must start with a letter or number, can include dashes ('-') and can be up to 35 characters long.
46 lines
1.6 KiB
46 lines
1.6 KiB
# Maintainer: Simon Legner <Simon.Legner@gmail.com> |
|
# Contributor: George Rawlinson <george@rawlinson.net.nz> |
|
|
|
pkgname=rollup |
|
pkgver=2.77.2 |
|
pkgrel=1 |
|
pkgdesc='Next-generation ES6 module bundler' |
|
arch=(any) |
|
url='https://rollupjs.org/' |
|
license=('MIT') |
|
depends=('nodejs') |
|
makedepends=('npm' 'jq') |
|
source=("$pkgname-$pkgver.tar.gz::https://registry.npmjs.org/$pkgname/-/$pkgname-$pkgver.tgz") |
|
noextract=("$pkgname-$pkgver.tar.gz") |
|
sha512sums=('9bfe18cd880b7293106f15f736602a0efc0b013673c6df1b21e80eefc1592e5fa502028905dd4344039e12265c28e20e3e3c44e9ec075873601846a5157bb3d6') |
|
b2sums=('7f1c11cd77d089ad8e512f87bed003491c161615ceb537c938fb6107a68bd780c4ef49f42119b9ae277d768cc88e3b4ee628833ac2d802ea69a5a1cdda5cc7ec') |
|
|
|
package() { |
|
local NPM_FLAGS=(--no-audit --no-fund --no-update-notifier) |
|
|
|
npm install \ |
|
--global \ |
|
--prefix "$pkgdir/usr" \ |
|
--cache "$srcdir/npm-cache" \ |
|
"${NPM_FLAGS[@]}" \ |
|
"$pkgname-$pkgver.tar.gz" |
|
|
|
# install licenses |
|
install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" \ |
|
"$pkgdir/usr/lib/node_modules/rollup/LICENSE.md" |
|
|
|
# install documentation |
|
install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" \ |
|
"$pkgdir/usr/lib/node_modules/rollup/"{CHANGELOG,README}.md |
|
|
|
# remove references to ${src,pkg}dir |
|
local tmppackage="$(mktemp)" |
|
local pkgjson="$pkgdir/usr/lib/node_modules/$pkgname/package.json" |
|
jq '.|=with_entries(select(.key|test("_.+")|not))' "$pkgjson" > "$tmppackage" |
|
mv "$tmppackage" "$pkgjson" |
|
chmod 644 "$pkgjson" |
|
|
|
# npm gives ownership of ALL FILES to build user |
|
# https://bugs.archlinux.org/task/63396 |
|
chown -R root:root "$pkgdir" |
|
}
|
|
|