45 lines
1.1 KiB
Bash
45 lines
1.1 KiB
Bash
# Maintainer: George Rawlinson <grawlinson@archlinux.org>
|
|
|
|
pkgname=cl-fad
|
|
pkgver=0.7.6.r9.g3f4d32d
|
|
pkgrel=1
|
|
pkgdesc='A portable pathname library for Common Lisp'
|
|
arch=('any')
|
|
url='https://edicl.github.io/cl-fad/'
|
|
license=('BSD')
|
|
depends=('common-lisp' 'cl-asdf' 'cl-bordeaux-threads' 'cl-alexandria')
|
|
makedepends=('git')
|
|
checkdepends=('sbcl' 'cl-ppcre' 'cl-unit-test')
|
|
_commit='3f4d32d3aa1093966046d001411a852eb8f4b535'
|
|
source=(
|
|
"$pkgname::git+https://github.com/edicl/cl-fad#commit=$_commit"
|
|
'run-tests.lisp'
|
|
)
|
|
b2sums=('SKIP'
|
|
'fedbf7df168ff548936ed81a3fa229eeb9e21d6c6d510f0242a8e734006a04ddcfd88c290d77bde9c92c168fbbbc1757e96da524708091358460099accd9f5b2')
|
|
|
|
pkgver() {
|
|
cd "$pkgname"
|
|
|
|
git describe --tags | sed -e 's/^v//' -e 's/-/.r/' -e 's/-/./g'
|
|
}
|
|
|
|
check() {
|
|
cd "$pkgname"
|
|
|
|
sbcl --script ../run-tests.lisp
|
|
}
|
|
|
|
package() {
|
|
cd "$pkgname"
|
|
|
|
# library
|
|
install -vDm644 -t "$pkgdir/usr/share/common-lisp/source/$pkgname" ./*.{lisp,asd,system}
|
|
|
|
# documentation
|
|
install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README CHANGELOG docs/index.html
|
|
|
|
# license
|
|
install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
|
|
}
|