# Maintainer: George Rawlinson <grawlinson@archlinux.org>

pkgname=python-pydeps
_name=${pkgname#python-}
pkgver=1.10.24
pkgrel=1
pkgdesc='Python module dependency graphs'
arch=('any')
url='https://github.com/thebjorn/pydeps'
license=('BSD')
depends=(
  'python'
  'python-yaml'
  'python-stdlib-list'
  'graphviz'
)
makedepends=('git' 'python-setuptools')
checkdepends=('python-pytest')
_commit='aed17eb135fa79611524dfe0ba2778a00e9d0ab1'
source=("$pkgname::git+$url.git#commit=$_commit")
b2sums=('SKIP')

pkgver() {
  cd "$pkgname"

  git describe --tags | sed 's/^v//'
}

build() {
  cd "$pkgname"

  python setup.py build
}

check() {
  cd "$pkgname"

  # figure out why package can't find pip
  # (even if it is installed as a dependency)
  pytest --ignore tests/test_package_names.py
}

package() {
  cd "$pkgname"

  python setup.py install --root="$pkgdir" --optimize=1

  # documentation
  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.rst

  # license
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}