# Maintainer: George Rawlinson <grawlinson@archlinux.org>
# Contributor: Aleksej Komarov <stylemistake@gmail.com>
# Upstream: Bitwig GmbH <support@bitwig.com>

pkgname=bitwig-studio
pkgver=4.4.8
pkgrel=1
pkgdesc='Digital audio workstation for music production, remixing and live performance'
arch=('x86_64')
url='https://www.bitwig.com'
license=('custom:bitwig')
groups=('pro-audio')
depends=(
  'gtk3'
  'libxkbcommon-x11'
  'xcb-util'
  'xcb-util-wm'
)
optdepends=(
  'alsa-lib: alsa audio backend'
  'ffmpeg: mp3 support'
  'jack: jack audio backend'
  'pipewire: pipewire audio backend'
  'pulseaudio: pulseaudio audio backend'
)
provides=('vst-host' 'vst3-host' 'clap-host')
options=('!strip')
source=("$pkgname-$pkgver.deb::https://downloads.bitwig.com/stable/$pkgver/$pkgname-$pkgver.deb")
sha512sums=('97d6a4c257e35f1d24b1457caa348d97687462efe384a5a5038d2f7621f1a8f99234f269e52a9c7a663e6f74cabca152f6b5f56e0d01ae8d3f87675d5b235bba')
b2sums=('f61ef59630eb8c00c11e07956ffb80ae6b67c723515d5652eba0ff47d9f8c2cbada5dd619dbd08b7d34ab6ef3f09ebd324204951c560590b42c2aefb5403affe')

package() {
  bsdtar \
    --extract \
    --file data.tar.xz \
    --directory "$pkgdir"

  # license
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" "$pkgdir/opt/$pkgname/EULA.txt"
}