# Maintainer: George Rawlinson <grawlinson@archlinux.org>

pkgname=python-pydeps
_name=${pkgname#python-}
pkgver=1.10.12
pkgrel=2
pkgdesc="Python module dependency graphs"
arch=('any')
url="https://github.com/thebjorn/pydeps"
license=('BSD')
depends=('python' 'python-yaml' 'python-stdlib-list' 'graphviz')
makedepends=('python-setuptools')
checkdepends=('python-pytest')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha512sums=('4ff7fea75a5f683c9d80dfef84f7729a67944a984513985472575996e8fc33c9c60725c79c2a76067b83f06d21c5e7b167b7a23bfba8c79d7243df20e9f7af51')
b2sums=('a7dcea7d3321e0f64fb5e97db17b94043543cc04b20033ec472ace753d1c7ec5dbfd1289583dcbeac1120e354b8ea748dd24fa8a4579e99c74ba8ed5d07b277b')

build() {
  cd "$_name-$pkgver"
  python setup.py build
}

check() {
  cd "$_name-$pkgver"

  # figure out why package can't find pip
  # (even if it is installed as a dependency)
  pytest --ignore tests/test_package_names.py
}

package() {
  cd "$_name-$pkgver"

  python setup.py install --root="$pkgdir" --optimize=1

  # documentation
  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.rst

  # license
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}