# Maintainer: George Rawlinson <grawlinson@archlinux.org>
# Contributor: Mark Wagie <mark dot wagie at tutanota dot com>
# Contributor: Thomas Andrejak <thomas.andrejak@gmail.com>

pkgname=python-croniter
_pkgname="${pkgname#python-}"
pkgver=1.1.0
pkgrel=2
pkgdesc="Provides iteration for the datetime object with a cron like format"
arch=('any')
url="https://github.com/kiorky/croniter"
license=('MIT')
depends=('python-dateutil' 'python-natsort')
makedepends=('python-setuptools')
checkdepends=('python-pytest' 'python-pytz')
source=("$pkgname-$pkgver.tar.gz::https://pypi.org/packages/source/${_pkgname:0:1}/$_pkgname/$_pkgname-$pkgver.tar.gz")
sha512sums=('ccc56e912d5ff684ec930f87ab096b0a739191014a2d0a76febddf0fe4155a6c319cf28011bea7b8f8034218a35813db65c3d4911ff575878a12f8fe1f75720e')
b2sums=('0c01d801b55b0fd6189d5b35f7493580aa25ea18e8be061152c6642fd05a9075c1211578124cd945bb754fda4704f637069a98c5080e41ce369cc3c959b35edf')

build() {
  cd "$_pkgname-$pkgver"
  python setup.py build
}

check() {
  cd "$_pkgname-$pkgver"
  pytest
}

package() {
  cd "$_pkgname-$pkgver"
  python setup.py install --root="$pkgdir" --optimize=1 --skip-build

  # license
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" docs/LICENSE

  # documentation
  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.rst docs/CHANGES.rst
}