# Maintainer: George Rawlinson <grawlinson@archlinux.org>
# Contributor: Aleksej Komarov <stylemistake@gmail.com>
# Upstream: Bitwig GmbH <support@bitwig.com>

pkgname=bitwig-studio
pkgver=4.4.6
pkgrel=1
pkgdesc='Digital audio workstation for music production, remixing and live performance'
arch=('x86_64')
url='https://www.bitwig.com'
license=('custom:bitwig')
groups=('pro-audio')
depends=(
  'gtk3'
  'libxkbcommon-x11'
  'xcb-util'
  'xcb-util-wm'
)
optdepends=(
  'alsa-lib: alsa audio backend'
  'ffmpeg: mp3 support'
  'jack: jack audio backend'
  'pipewire: pipewire audio backend'
  'pulseaudio: pulseaudio audio backend'
)
provides=('vst-host' 'vst3-host' 'clap-host')
options=('!strip')
source=("$pkgname-$pkgver.deb::https://downloads.bitwig.com/stable/$pkgver/$pkgname-$pkgver.deb")
sha512sums=('5e802d817d386852d2bf666269124c24bf094c563d47914362cd414b424376ebba021bee1191ddf1a9ab8be2a343751c2e8c36dec432e15362e7f26595f499e2')
b2sums=('31932d91ed62b55445e8dd9ef34c03b90298121c453bb32416e9235ba700f9ebaad508f370899cb82bd1fbbce106f0fac99a8aa790a082b94f5888dcafb97a40')

package() {
  bsdtar \
    --extract \
    --file data.tar.xz \
    --directory "$pkgdir"

  # license
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" "$pkgdir/opt/$pkgname/EULA.txt"
}