# Maintainer: George Rawlinson <grawlinson@archlinux.org>
# Contributor: Mark Wagie <mark dot wagie at tutanota dot com>
# Contributor: Thomas Andrejak <thomas.andrejak@gmail.com>

pkgname=python-croniter
pkgver=1.3.5
pkgrel=1
pkgdesc='Provides iteration for the datetime object with a cron like format'
arch=('any')
url='https://github.com/kiorky/croniter'
license=('MIT')
depends=('python' 'python-dateutil' 'python-natsort')
makedepends=('git' 'python-setuptools')
checkdepends=('python-pytest' 'python-pytz')
_commit='8fdf5b196f75cc0bc5e3531732891d6e41b19617'
source=("$pkgname::git+$url.git#commit=$_commit")
b2sums=('SKIP')

pkgver() {
  cd "$pkgname"

  git describe --tags | sed 's/^v//'
}

build() {
  cd "$pkgname"

  python setup.py build
}

check() {
  cd "$pkgname"

  pytest
}

package() {
  cd "$pkgname"

  python setup.py install --root="$pkgdir" --optimize=1 --skip-build

  # license
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" docs/LICENSE

  # documentation
  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.rst docs/CHANGES.rst
}