# Maintainer: George Rawlinson <grawlinson@archlinux.org>
# Contributor: Mario Finelli <mario at finel dot li>
# Contributor: farwayer <farwayer at gmail dot com>

pkgname=ruby-rubocop
_gemname="${pkgname#ruby-}"
pkgver=1.31.1
pkgrel=1
pkgdesc='A Ruby static code analyzer and formatter'
arch=('any')
url='https://rubocop.org'
license=('MIT')
depends=(
  'ruby'
  'ruby-parallel'
  'ruby-parser'
  'ruby-rainbow'
  'ruby-regexp_parser'
  'ruby-rexml'
  'ruby-rubocop-ast'
  'ruby-ruby-progressbar'
  'ruby-unicode-display_width'
)
makedepends=('ruby-rdoc')
options=('!emptydirs')
source=("https://rubygems.org/downloads/$_gemname-$pkgver.gem")
noextract=("$_gemname-$pkgver.gem")
sha512sums=('7a165b3d4d2a3553abe77d8e8e770c5d76d5f949756ffdccab8c6645f89eee260047e8a0b64fd81caacfc8ebac3e13e2dd372e775bfd9534894bbd312a17dd5b')
b2sums=('73598bf7a711475bb97e9785032e9f8976e975f6754b1a224035531691b0d34c34c55c529e1e54dff50a61d8a86b5b722dae8ed4c7a5a9004b90673a9e0cd5b9')

package() {
  local _gemdir="$(ruby -e'puts Gem.default_dir')"

  gem install \
    --verbose \
    --ignore-dependencies \
    --no-document \
    --no-user-install \
    --install-dir "$pkgdir/$_gemdir" \
    --bindir "$pkgdir/usr/bin" \
    "$_gemname-$pkgver.gem"

  # delete cache
  cd "$pkgdir/$_gemdir"
  rm -vrf cache

  cd "gems/$_gemname-$pkgver"

  # move documentation
  install -vd "$pkgdir/usr/share/doc/$pkgname"
  mv -vt "$pkgdir/usr/share/doc/$pkgname" README.md

  # move license
  install -vd "$pkgdir/usr/share/licenses/$pkgname"
  mv -vt "$pkgdir/usr/share/licenses/$pkgname" LICENSE.txt

  # generate reproducible documentation
  install -vd "$pkgdir/$_gemdir/doc/$_gemname-$pkgver"
  cd "$pkgdir/$_gemdir/gems/$_gemname-$pkgver"
  rdoc \
    --format ri \
    --output "$pkgdir$_gemdir/doc/$_gemname-$pkgver/ri" \
    ./lib
  # delete unnecessary rdoc metadata file
  rm -f "$pkgdir$_gemdir/doc/$_gemname-$pkgver/ri/created.rid"
}