# Maintainer: George Rawlinson <grawlinson@archlinux.org>
# Contributor: Aleksej Komarov <stylemistake@gmail.com>
# Upstream: Bitwig GmbH <support@bitwig.com>

pkgname=bitwig-studio
pkgver=4.4.2
pkgrel=1
pkgdesc='Digital audio workstation for music production, remixing and live performance'
arch=('x86_64')
url='https://www.bitwig.com'
license=('custom:bitwig')
groups=('pro-audio')
depends=(
  'gtk3'
  'libxkbcommon-x11'
  'xcb-util'
  'xcb-util-wm'
)
optdepends=(
  'alsa-lib: alsa audio backend'
  'ffmpeg: mp3 support'
  'jack: jack audio backend'
  'pipewire: pipewire audio backend'
  'pulseaudio: pulseaudio audio backend'
)
provides=('vst-host' 'vst3-host' 'clap-host')
options=('!strip')
source=("$pkgname-$pkgver.deb::https://downloads.bitwig.com/stable/$pkgver/$pkgname-$pkgver.deb")
sha512sums=('5ceb8e68604c68e3ec53913867bf0ab910ebe9d65f18314194e5e11b8b34a01aeba7f0df3ad599214bb224b7251c388c374eb4042ca7c98f90c33ce6eacbc8d0')
b2sums=('752c661906e4c3af169b8fb32cfef3892e633c270bb7f2d64962810729501b18fdcab34f927c66aab1a7089e1caca19d220284d4a452fd9712eae5f0ec6b7ee4')

package() {
  bsdtar \
    --extract \
    --file data.tar.xz \
    --directory "$pkgdir"

  # license
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" "$pkgdir/opt/$pkgname/EULA.txt"
}