# Maintainer: George Rawlinson <george@rawlinson.net.nz>

pkgname=nodejs-homebridge-denon-tv
_pkgname="${pkgname#nodejs-}"
pkgver=3.10.61
pkgrel=1
pkgdesc="Homebridge plugin for Denon/Marantz AV receivers"
arch=('any')
url="https://github.com/grzegorz914/homebridge-denon-tv"
license=('MIT')
depends=('homebridge')
makedepends=('npm')
options=('!strip')
source=("$_pkgname-$pkgver.tar.gz::https://registry.npmjs.org/$_pkgname/-/$_pkgname-$pkgver.tgz")
noextract=("$_pkgname-$pkgver.tar.gz")
b2sums=('f7b1f7b3aeaa379d7589a24d22cf0348f5e6c13eff83be7ccdcecc3bb01da5a7d5692f482b2940404ffa30f26fec2ec2f892510aea6d1876b0c25dba44f27143')

package() {
  npm install --global --prefix "$pkgdir/usr" "$_pkgname-$pkgver.tar.gz"

  # Non-deterministic race in npm gives 777 permissions to random directories
  # See https://github.com/npm/cli/issues/1103 for details
  find "$pkgdir/usr" -type d -exec chmod 755 {} +

  # npm gives ownership of ALL FILES to build user
  # https://bugs.archlinux.org/task/63396
  chown -R root:root "$pkgdir"

  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" \
    "$pkgdir/usr/lib/node_modules/$_pkgname/LICENSE"
}