# Maintainer: George Rawlinson <grawlinson@archlinux.org>

pkgname=python-pydeps
_name=${pkgname#python-}
pkgver=1.10.5
pkgrel=1
pkgdesc="Python module dependency graphs"
arch=('any')
url="https://github.com/thebjorn/pydeps"
license=('BSD')
depends=('python' 'python-yaml' 'python-stdlib-list' 'graphviz')
makedepends=('python-setuptools')
checkdepends=('python-pytest')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha512sums=('5fc92759c7c08d68bde96436555bb08c21b226dc75b73e5ca22a70b247f75dc024e9f687d0a61993ce1c8cfdda6be0ec189a83e59cf4a87894f073a576de8ef7')
b2sums=('6dc7a9361949014fa64dbf913748b1a8b599471a6fccf7924de91bf8eebacce10d34959244bb092d8f51725b328d9646c89927d9620b146c814389ac4ff3f2ca')

build() {
  cd "$_name-$pkgver"
  python setup.py build
}

check() {
  cd "$_name-$pkgver"

  # figure out why package can't find pip
  # (even if it is installed as a dependency)
  pytest --ignore tests/test_package_names.py
}

package() {
  cd "$_name-$pkgver"

  python setup.py install --root="$pkgdir" --optimize=1

  # documentation
  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.rst

  # license
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}