# Maintainer: George Rawlinson <grawlinson@archlinux.org>

pkgname=python-pydeps
_name=${pkgname#python-}
pkgver=1.10.14
pkgrel=1
pkgdesc="Python module dependency graphs"
arch=('any')
url="https://github.com/thebjorn/pydeps"
license=('BSD')
depends=(
  'python'
  'python-yaml'
  'python-stdlib-list'
  'graphviz'
)
makedepends=('python-setuptools')
checkdepends=('python-pytest')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha512sums=('300b28ce2692bb997e29880d0ee745eaf6808954ab7dede1bc66e4a84edacdd0f49d4d8ec0112befee37af5bcacf69be93a91da36080574c0a432294c7381477')
b2sums=('64ebf4af8acfdbd2ffdaba18050c81fe18bb0d37bbb2054e3891cd0ff4a14d3f923cdd4a8e53a6d706c1733bc48b73c7da825a2e12c1aea8b614000b7a6b129d')

build() {
  cd "$_name-$pkgver"
  python setup.py build
}

check() {
  cd "$_name-$pkgver"

  # figure out why package can't find pip
  # (even if it is installed as a dependency)
  pytest --ignore tests/test_package_names.py
}

package() {
  cd "$_name-$pkgver"

  python setup.py install --root="$pkgdir" --optimize=1

  # documentation
  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.rst

  # license
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}