# Maintainer: George Rawlinson <george@rawlinson.net.nz>

_gemname=oj
pkgname=ruby-$_gemname
pkgver=3.13.5
pkgrel=1
pkgdesc='The fastest JSON parser and object serializer'
arch=('x86_64')
url='https://github.com/ohler55/oj'
license=('MIT')
depends=('ruby')
makedepends=('ruby-rdoc')
options=(!emptydirs)
source=("https://rubygems.org/downloads/$_gemname-$pkgver.gem")
noextract=("$_gemname-$pkgver.gem")
b2sums=('ff150b944d2fba00ca28e85e4aff8786c2766979dd0c0f7b38273da3d66c263d00fa060000ec8c5cc4d7ba409eff7bd470b15a258c91ab5ab665095d2acee6c3')

package() {
  local _gemdir="$(ruby -e'puts Gem.default_dir')"

  gem install \
    --verbose \
    --ignore-dependencies \
    --no-user-install \
    --install-dir "$pkgdir/$_gemdir" \
    --bindir "$pkgdir/usr/bin" \
    "$_gemname-$pkgver.gem"

  # delete cache
  cd "$pkgdir/$_gemdir"
  rm -vrf cache

  # delete unnecessary files & folders
  rm -vrf "extensions/$CARCH-linux/$(basename $_gemdir)/$_gemname-$pkgver/gem_make.out"
  cd "gems/$_gemname-$pkgver"
  rm -vrf test ext

  # move documentation
  install -vd "$pkgdir/usr/share/doc/$pkgname"
  mv -v README.md pages "$pkgdir/usr/share/doc/$pkgname"

  # license
  install -vd "$pkgdir/usr/share/licenses/$pkgname"
  mv -v LICENSE "$pkgdir/usr/share/licenses/$pkgname"
}