# Maintainer: George Rawlinson <grawlinson@archlinux.org>

pkgname=python-pydeps
_name=${pkgname#python-}
pkgver=1.10.10
pkgrel=1
pkgdesc="Python module dependency graphs"
arch=('any')
url="https://github.com/thebjorn/pydeps"
license=('BSD')
depends=('python' 'python-yaml' 'python-stdlib-list' 'graphviz')
makedepends=('python-setuptools')
checkdepends=('python-pytest')
source=("$pkgname-$pkgver.tar.gz::$url/archive/v$pkgver.tar.gz")
sha512sums=('18605a7c3886c704a6a3fdbdde0da1aea9fe5ef8411489167ed9a98cbd666e3e18b714e2d9bff5c04e5802f40cc68ea6ae17f20a63660bdbaaf8c3f9d52a4c53')
b2sums=('c456bd7b313e2518f9fcc06d5eddfa7a8eb9a81cd94fc6cc7e242dc3985d71771b0e4c579eaa8e134ee81a9d0d0013bfb42d02f4922e852e17f6520959c431b4')

build() {
  cd "$_name-$pkgver"
  python setup.py build
}

check() {
  cd "$_name-$pkgver"

  # figure out why package can't find pip
  # (even if it is installed as a dependency)
  pytest --ignore tests/test_package_names.py
}

package() {
  cd "$_name-$pkgver"

  python setup.py install --root="$pkgdir" --optimize=1

  # documentation
  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.rst

  # license
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}