# Maintainer: George Rawlinson <grawlinson@archlinux.org>

pkgname=cl-trivial-backtrace
_pkgname="${pkgname#cl-}"
pkgver=1.1.0.r20.g6eb65bd
_pkgcommit='3d39b1101e6fc59ef57c0ef049f3411d6da3e878'
_pkgver=1.1.0 
pkgrel=1
pkgdesc='Portable API to work with backtraces in Common Lisp'
arch=('any')
url='https://github.com/gwkkwg/trivial-backtrace'
license=('MIT')
depends=('common-lisp' 'cl-asdf')
makedepends=('git' 'sbcl')
#checkdepends=('cl-lift')
_commit='6eb65bde7229413040c81d42ea22f0e4c9c8cfc9'
source=("$pkgname::git+$url#commit=$_commit")
b2sums=('SKIP')

pkgver() {
  cd "$pkgname"

  printf '%s.r%s.g%s'  "$_pkgver" "$(git rev-list --count ${_pkgcommit}..HEAD)" "$(git rev-parse --short HEAD)"
}

package() {
  cd "$pkgname"

  # create directories
  install -vd \
    "$pkgdir/usr/share/common-lisp/source/$_pkgname" \
    "$pkgdir/usr/share/common-lisp/systems"

  # library
  cp -vr \
    dev test \
    lift-standard.config ./*.asd \
    "$pkgdir/usr/share/common-lisp/source/$_pkgname"

  pushd "$pkgdir/usr/share/common-lisp/systems"
  ln -s "../source/$_pkgname"/*.asd .
  popd

  # license
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" COPYING
}