# Maintainer: George Rawlinson <grawlinson@archlinux.org>

_gemname=rubocop-ast
pkgname=ruby-$_gemname
pkgver=1.10.0
pkgrel=1
pkgdesc="RuboCop's AST extensions and Node/NodePattern functionality"
arch=('any')
url="https://github.com/rubocop/rubocop-ast"
license=('MIT')
depends=('ruby' 'ruby-parser')
makedepends=('ruby-rdoc')
options=('!emptydirs')
source=("https://rubygems.org/downloads/$_gemname-$pkgver.gem")
noextract=("$_gemname-$pkgver.gem")
b2sums=('4596c94b75a85fc528bfe3891c14abe696f2ca9666603b905417e060955265a99558517cd0310168c9b749fbc5c1824c01ad0d041fcc756317113bf356756389')

package() {
  local _gemdir="$(ruby -e'puts Gem.default_dir')"

  gem install \
    --verbose \
    --ignore-dependencies \
    --no-user-install \
    --install-dir "$pkgdir/$_gemdir" \
    --bindir "$pkgdir/usr/bin" \
    "$_gemname-$pkgver.gem"

  # delete cache
  cd "$pkgdir/$_gemdir"
  rm -vrf cache

  cd "gems/$_gemname-$pkgver"

  # move documentation
  install -vd "$pkgdir/usr/share/doc/$pkgname"
  mv -vt "$pkgdir/usr/share/doc/$pkgname" README.md

  # move license
  install -vd "$pkgdir/usr/share/licenses/$pkgname"
  mv -vt "$pkgdir/usr/share/licenses/$pkgname" LICENSE.txt
}