# Maintainer: George Rawlinson <george@rawlinson.net.nz>

_gemname=oj
pkgname=ruby-$_gemname
pkgver=3.13.4
pkgrel=1
pkgdesc='The fastest JSON parser and object serializer'
arch=('x86_64')
url='https://github.com/ohler55/oj'
license=('MIT')
depends=('ruby')
makedepends=('ruby-rdoc')
options=(!emptydirs)
source=("https://rubygems.org/downloads/$_gemname-$pkgver.gem")
noextract=("$_gemname-$pkgver.gem")
b2sums=('befcdead9259a16eb1db65e8c4160b4b94392e9bf726ec1b0bd93068bf37e3627e02e1128855a0e71046e1932165735d87ff6e0188bf3c61122b40830b73a14e')

package() {
  local _gemdir="$(ruby -e'puts Gem.default_dir')"

  gem install \
    --verbose \
    --ignore-dependencies \
    --no-user-install \
    --install-dir "$pkgdir/$_gemdir" \
    --bindir "$pkgdir/usr/bin" \
    "$_gemname-$pkgver.gem"

  # delete cache
  cd "$pkgdir/$_gemdir"
  rm -vrf cache

  # delete unnecessary files & folders
  rm -vrf "extensions/$CARCH-linux/$(basename $_gemdir)/$_gemname-$pkgver/gem_make.out"
  cd "gems/$_gemname-$pkgver"
  rm -vrf test ext

  # move documentation
  install -vd "$pkgdir/usr/share/doc/$pkgname"
  mv -v README.md pages "$pkgdir/usr/share/doc/$pkgname"

  # license
  install -vd "$pkgdir/usr/share/licenses/$pkgname"
  mv -v LICENSE "$pkgdir/usr/share/licenses/$pkgname"
}