# Maintainer: George Rawlinson <grawlinson@archlinux.org>
# Contributor: Aleksej Komarov <stylemistake@gmail.com>
# Upstream: Bitwig GmbH <support@bitwig.com>

pkgname=bitwig-studio
pkgver=4.4
pkgrel=1
pkgdesc='Digital audio workstation for music production, remixing and live performance'
arch=('x86_64')
url='https://www.bitwig.com'
license=('custom:bitwig')
groups=('pro-audio')
depends=(
  'gtk3'
  'libxkbcommon-x11'
  'xcb-util'
  'xcb-util-wm'
)
optdepends=(
  'alsa-lib: alsa audio backend'
  'ffmpeg: mp3 support'
  'jack: jack audio backend'
  'pipewire: pipewire audio backend'
  'pulseaudio: pulseaudio audio backend'
)
provides=('vst-host' 'vst3-host' 'clap-host')
options=('!strip')
source=("$pkgname-$pkgver.deb::https://downloads.bitwig.com/stable/$pkgver/$pkgname-$pkgver.deb")
sha512sums=('c7a1a7f72cc15b122c24065a37b6f3dbcf1f81bc66cee2384e6a19c439eebcb90c2a2efbad5561e1bc45b3ca1b2ffe76e087e9c6f018bf553e79b042fb9cabf1')
b2sums=('eaa21d031da8f806c1e15365eca58053ca32ef5e7d1ba6a33cc9aff339e9928a80bd6ad7a446e9b6e1900c44abff97d55bdd8b424ad5dc5cb5e2287f8c6e6529')

package() {
  bsdtar \
    --extract \
    --file data.tar.xz \
    --directory "$pkgdir"

  # license
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" "$pkgdir/opt/$pkgname/EULA.txt"
}