diff --git a/dart-sass/PKGBUILD b/dart-sass/PKGBUILD
new file mode 100644
index 0000000..ef15eb1
--- /dev/null
+++ b/dart-sass/PKGBUILD
@@ -0,0 +1,38 @@
+# Maintainer: George Rawlinson <grawlinson@archlinux.org>
+# Contributor: Thayne McCombs <astrothayne@gmail.com>
+
+pkgname=dart-sass
+pkgver=1.43.5
+pkgrel=1
+pkgdesc="Sass makes CSS fun again"
+arch=('x86_64')
+url='http://sass-lang.com/'
+license=('MIT')
+makedepends=('dart')
+options=('!strip')
+provides=('sass')
+conflicts=('ruby-sass')
+source=("$pkgname-$pkgver.tar.gz::https://github.com/sass/$pkgname/archive/$pkgver.tar.gz")
+b2sums=('8b02eaab47bddd9466e55edfead40895833eb635616dfd4c30206e6bed12227a6ac2a19521be0a246ba9b8cdd5fd90b5c0f821446ce825f6ddd210fbd39965a1')
+
+prepare() {
+  cd "$pkgname-$pkgver"
+
+  # download dependencies
+  pub get
+}
+
+build() {
+  cd "$pkgname-$pkgver"
+  dart compile exe -Dversion=$pkgver -o sass bin/sass.dart
+}
+
+package() {
+  cd "$pkgname-$pkgver"
+
+  # binary
+  install -vDm755 -t "$pkgdir/usr/bin" sass
+
+  # license
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+}