addpkg: hck 0.7.1-1

hck/PKGBUILD

@@ -0,0 +1,43 @@
+# Maintainer: George Rawlinson <grawlinson@archlinux.org>
+# Contributor: aulonsal <aulonsal at gmail dot com>
+
+pkgname=hck
+pkgver=0.7.1
+pkgrel=1
+pkgdesc='A sharp cut(1) clone'
+arch=('x86_64')
+url="https://github.com/sstadick/hck"
+license=('Unlicense' 'MIT')
+depends=('gcc-libs')
+makedepends=('git' 'rust' 'cmake')
+options=('!lto')
+_commit='aa6988c51c372074222e056e8f7fc8b332272b4e'
+source=("$pkgname::git+$url.git#commit=$_commit")
+md5sums=('SKIP')
+
+prepare() {
+  cd "$pkgname"
+
+  # download dependencies
+  cargo fetch --locked --target "$CARCH-unknown-linux-gnu"
+}
+
+build() {
+	cd "$pkgname"
+	cargo build --release --frozen
+}
+
+check() {
+	cd "$pkgname"
+	cargo test --frozen
+}
+
+package() {
+	cd "$pkgname"
+
+  install -vDm755 -t "$pkgdir/usr/bin" target/release/hck
+
+	install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE-MIT UNLICENSE
+
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
+}