addpkg: distrobuilder-create 0.1-1

distrobuilder-create/PKGBUILD

@@ -0,0 +1,40 @@
+# Maintainer: George Rawlinson <grawlinson@archlinux.org>
+
+pkgname=distrobuilder-create
+pkgver=0.1
+pkgrel=1
+pkgdesc="Automatically create images with distrobuilder"
+arch=('any')
+url="https://git.little.kiwi/grawlinson/distrobuilder-create"
+license=('GPL')
+depends=('lxd' 'distrobuilder' 'sudo' 'systemd')
+checkdepends=('shfmt' 'shellcheck')
+source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
+sha512sums=('687c88453d09ab7d76e3f478ff32f71db85b17652598644f3557034d0ffa82dd40a59069012a0849aa4ccdf34c882fe7df0ab22063e8ceb79a0488d58fa15196')
+b2sums=('729bece0188ac50b8aeac0111a2da9b6256af254522726151ddd96600c351cc96dc18c329a90b84489c211da4c07bb90209d584dde624ec9b098ae3e0e2b647a')
+
+check() {
+  cd "$pkgname"
+
+  # check formatting with shfmt
+  shfmt -i 2 -l distrobuilder-create.sh
+
+  # check syntax with shellcheck
+  shellcheck distrobuilder-create.sh
+}
+
+package() {
+  cd "$pkgname"
+
+  # script
+  install -vDm755 distrobuilder-create.sh "$pkgdir/usr/bin/$pkgname"
+
+  # drop-in sudoers snippet
+  install -vDm440 sudoers.conf "$pkgdir/etc/sudoers.d/$pkgname"
+
+  # systemd integration
+  install -vDm644 systemd.service "$pkgdir/usr/lib/systemd/system/$pkgname@.service"
+  install -vDm644 systemd.timer "$pkgdir/usr/lib/systemd/system/$pkgname@.timer"
+  install -vDm644 tmpfiles.conf "$pkgdir/usr/lib/tmpfiles.d/$pkgname.conf"
+  install -vDm644 sysusers.conf "$pkgdir/usr/lib/sysusers.d/$pkgname.conf"
+}