rmpkg: sad

primary
George Rawlinson 2021-08-03 04:16:37 +00:00
parent a7986ce708
commit 1f6d471dde
Signed by: grawlinson
GPG Key ID: E0959FEA8B550539
1 changed files with 0 additions and 54 deletions

View File

@ -1,54 +0,0 @@
# Maintainer: George Rawlinson <grawlinson@archlinux.org>
# Contributor: Joost Bremmer <contact at madeofmagicandwires dot online>
# Contributor: Eliezio Oliveira <eliezio@pm.me>
# Contributor: Matthew Gamble <internet@matthewgamble.net>
pkgname=sad
pkgver=0.4.8
pkgrel=3
pkgdesc="Space Age seD"
arch=('x86_64')
url="https://github.com/ms-jpq/sad"
license=('MIT')
makedepends=('rust')
optdepends=(
'fzf: for tui usage'
'diff-so-fancy: for diff colourizer'
'git-delta: for diff colourizer'
)
source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
b2sums=('95591e5bce26dfa9507ced99b0197e8d103a9b0fbda6b712ec0296188563092d9dfcd0744462c53111f6a3ca1ab7aa2834b621614edd3731f2d01db557fbb6f7')
prepare() {
cd "$pkgname-$pkgver"
# cargo's lockfile is currently out of sync :(
cargo update
# download dependencies
cargo fetch --locked
}
build() {
cd "$pkgname-$pkgver"
cargo build --release --offline --locked --all-features
}
check() {
cd "$pkgname-$pkgver"
cargo test --locked
}
package() {
cd "$pkgname-$pkgver"
# binary
install -vDm755 -t "$pkgdir/usr/bin" "target/release/$pkgname"
# license
install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
# documentation
install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
}
# vim: set ts=2 sts=2 sw=2 et :