diff --git a/cl-fad/PKGBUILD b/cl-fad/PKGBUILD
new file mode 100644
index 0000000..b19c13f
--- /dev/null
+++ b/cl-fad/PKGBUILD
@@ -0,0 +1,53 @@
+# Maintainer: George Rawlinson <grawlinson@archlinux.org>
+
+pkgname=cl-fad
+pkgver=0.7.6.r9.g3f4d32d
+pkgrel=1
+pkgdesc='A portable pathname library for Common Lisp'
+arch=('any')
+url='https://edicl.github.io/cl-fad/'
+license=('BSD')
+depends=('common-lisp' 'cl-asdf' 'cl-bordeaux-threads' 'cl-alexandria')
+makedepends=('git')
+checkdepends=('sbcl' 'cl-ppcre' 'cl-unit-test')
+_commit='3f4d32d3aa1093966046d001411a852eb8f4b535'
+source=(
+  "$pkgname::git+https://github.com/edicl/cl-fad#commit=$_commit"
+  'run-tests.lisp'
+)
+b2sums=('SKIP'
+        'fedbf7df168ff548936ed81a3fa229eeb9e21d6c6d510f0242a8e734006a04ddcfd88c290d77bde9c92c168fbbbc1757e96da524708091358460099accd9f5b2')
+
+pkgver() {
+  cd "$pkgname"
+
+  git describe --tags | sed -e 's/^v//' -e 's/-/.r/' -e 's/-/./g'
+}
+
+check() {
+  cd "$pkgname"
+
+  sbcl --script ../run-tests.lisp
+}
+
+package() {
+  cd "$pkgname"
+
+  # create directories
+  install -vd \
+    "$pkgdir/usr/share/common-lisp/source/$pkgname" \
+    "$pkgdir/usr/share/common-lisp/systems"
+
+  # library
+  install -vDm644 -t "$pkgdir/usr/share/common-lisp/source/$pkgname" ./*.{lisp,asd,system}
+
+  pushd "$pkgdir/usr/share/common-lisp/systems"
+  ln -s "../source/$pkgname/$pkgname.asd" .
+  popd
+
+  # documentation
+  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README CHANGELOG docs/index.html
+
+  # license
+  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
+}
diff --git a/cl-fad/run-tests.lisp b/cl-fad/run-tests.lisp
new file mode 100644
index 0000000..d4bd2d1
--- /dev/null
+++ b/cl-fad/run-tests.lisp
@@ -0,0 +1,7 @@
+(require "asdf")
+
+(push (uiop/os:getcwd) asdf:*central-registry*)
+
+(asdf:load-system "cl-fad/test")
+
+(uiop:quit (if (asdf:test-system "cl-fad") 0 1))