addpkg: ruby-parallel 1.20.1-2

ruby-parallel/PKGBUILD

@@ -0,0 +1,38 @@
+# Maintainer: George Rawlinson <grawlinson@archlinux.org>
+# Contributor: Mario Finelli <mario at finel dot li>
+# Contributor: Benjamin Chrétien <chretien dot b plus aur at gmail dot com>
+
+_gemname=parallel
+pkgname=ruby-$_gemname
+pkgver=1.20.1
+pkgrel=2
+pkgdesc="Ruby: parallel processing made simple and fast"
+arch=('any')
+url="https://github.com/grosser/parallel"
+license=('MIT')
+depends=('ruby')
+options=('!emptydirs')
+source=("https://rubygems.org/downloads/$_gemname-$pkgver.gem")
+noextract=("$_gemname-$pkgver.gem")
+b2sums=('79d859335509bd6c73b176441865da89655ba8b9928345d774154aa1fc160c0ba5fbf1394e1999892e9a762a0fb9848eab3491e642b15116be9b7f34e291400c')
+
+package() {
+  local _gemdir="$(ruby -e'puts Gem.default_dir')"
+
+  gem install \
+    --ignore-dependencies \
+    --no-user-install \
+    --no-document \
+    --install-dir "$pkgdir/$_gemdir" \
+    --bindir "$pkgdir/usr/bin" \
+    "$_gemname-$pkgver.gem"
+
+  # delete cache
+  cd "$pkgdir/$_gemdir"
+  rm -vrf cache
+
+  # move license
+  cd "gems/$_gemname-$pkgver"
+  install -vd "$pkgdir/usr/share/licenses/$pkgname"
+  mv -vt "$pkgdir/usr/share/licenses/$pkgname" MIT-LICENSE.txt
+}