addpkg: python-cron-descriptor 1.2.24-1

primary
George Rawlinson 2021-08-26 01:51:58 +00:00
parent aa2f9324a5
commit 0b27eefef2
Signed by: grawlinson
GPG Key ID: E0959FEA8B550539
1 changed files with 36 additions and 0 deletions

View File

@ -0,0 +1,36 @@
# Maintainer: George Rawlinson <grawlinson@archlinux.org>
pkgname=python-cron-descriptor
_pkgname="${pkgname#python-}"
pkgver=1.2.24
pkgrel=1
pkgdesc="A Python library that converts cron expressions into human readable strings"
arch=('any')
url="https://github.com/Salamek/cron-descriptor"
license=('MIT')
depends=('python')
makedepends=('python-setuptools')
source=("$pkgname-$pkgver.tar.gz::$url/archive/$pkgver.tar.gz")
b2sums=('bf593431ffe52b58734c76ab9f065842d0423cd44d558a8efc75a97b3692cb11a9a43f0d9135eacc73087d0c184f73535fcfe4c9a62d12f7627c8ba99ad950f1')
build() {
cd "$_pkgname-$pkgver"
python setup.py build
}
check() {
cd "$_pkgname-$pkgver"
python -m unittest
}
package() {
cd "$_pkgname-$pkgver"
python setup.py install --root="$pkgdir" --optimize=1
# documentation
install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.md
cp -vr examples "$pkgdir/usr/share/doc/$pkgname"
# license
install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}