arch-pkgs/ruby-rubocop/PKGBUILD

# Maintainer: George Rawlinson <grawlinson@archlinux.org>
# Contributor: Mario Finelli <mario at finel dot li>
# Contributor: farwayer <farwayer at gmail dot com>

pkgname=ruby-rubocop
_gemname="${pkgname#ruby-}"
pkgver=1.30.1
pkgrel=1
pkgdesc='A Ruby static code analyzer and formatter'
arch=('any')
url='https://rubocop.org'
license=('MIT')
depends=(
  'ruby'
  'ruby-parallel'
  'ruby-parser'
  'ruby-rainbow'
  'ruby-regexp_parser'
  'ruby-rexml'
  'ruby-rubocop-ast'
  'ruby-ruby-progressbar'
  'ruby-unicode-display_width'
)
makedepends=('ruby-rdoc')
options=('!emptydirs')
source=("https://rubygems.org/downloads/$_gemname-$pkgver.gem")
noextract=("$_gemname-$pkgver.gem")
sha512sums=('eb2a91a5c5d081d89f0abc905faa48b944f3fdc10319ba91d505128bdfa92450b913e2c0b3c67b5864d18eb572b5a15d1200facfc3287cdc6719fed195b41533')
b2sums=('619aa43d01a325318d1c1b297b6fcac54eeb79fb586d29fab4d13e2e7d32b44702f4e9b314a891a713496889414c14069eb23e10b510e5c87e0ccdb9454b65de')

package() {
  local _gemdir="$(ruby -e'puts Gem.default_dir')"

  gem install \
    --verbose \
    --ignore-dependencies \
    --no-document \
    --no-user-install \
    --install-dir "$pkgdir/$_gemdir" \
    --bindir "$pkgdir/usr/bin" \
    "$_gemname-$pkgver.gem"

  # delete cache
  cd "$pkgdir/$_gemdir"
  rm -vrf cache

  cd "gems/$_gemname-$pkgver"

  # move documentation
  install -vd "$pkgdir/usr/share/doc/$pkgname"
  mv -vt "$pkgdir/usr/share/doc/$pkgname" README.md

  # move license
  install -vd "$pkgdir/usr/share/licenses/$pkgname"
  mv -vt "$pkgdir/usr/share/licenses/$pkgname" LICENSE.txt

  # generate reproducible documentation
  install -vd "$pkgdir/$_gemdir/doc/$_gemname-$pkgver"
  cd "$pkgdir/$_gemdir/gems/$_gemname-$pkgver"
  rdoc \
    --format ri \
    --output "$pkgdir$_gemdir/doc/$_gemname-$pkgver/ri" \
    ./lib
  # delete unnecessary rdoc metadata file
  rm -f "$pkgdir$_gemdir/doc/$_gemname-$pkgver/ri/created.rid"
}