arch-pkgs/ruby-oj/PKGBUILD

# Maintainer: George Rawlinson <george@rawlinson.net.nz>

_gemname=oj
pkgname=ruby-$_gemname
pkgver=3.13.1
pkgrel=1
pkgdesc='The fastest JSON parser and object serializer'
arch=('x86_64')
url='https://github.com/ohler55/oj'
license=('MIT')
depends=('ruby')
makedepends=('ruby-rdoc')
options=(!emptydirs)
source=("https://rubygems.org/downloads/$_gemname-$pkgver.gem")
noextract=("$_gemname-$pkgver.gem")
b2sums=('a77d194ab66a93abb6a9606c4b1697e4382dd1d7f4d1f59dedb370971c760feba221d6d881ce933632d98f63696695ae290f0709e78b36459c1c8cbf43b74242')

package() {
  local _gemdir="$(ruby -e'puts Gem.default_dir')"

  gem install \
    --verbose \
    --ignore-dependencies \
    --no-user-install \
    --install-dir "$pkgdir/$_gemdir" \
    --bindir "$pkgdir/usr/bin" \
    "$_gemname-$pkgver.gem"

  # delete cache
  cd "$pkgdir/$_gemdir"
  rm -vrf cache

  # delete unnecessary files & folders
  # TODO: investigate gem.build_complete (gem_build_complete_path)
  rm -vrf "extensions/$(uname -m)-linux/$(basename $(ruby -e'puts Gem.default_dir'))/$_gemname-$pkgver/gem_make.out"
  cd "gems/$_gemname-$pkgver"
  rm -vrf test ext

  # move documentation
  install -vd "$pkgdir/usr/share/doc/$pkgname"
  mv -v README.md pages "$pkgdir/usr/share/doc/$pkgname"

  # license
  install -vd "$pkgdir/usr/share/licenses/$pkgname"
  mv -v LICENSE "$pkgdir/usr/share/licenses/$pkgname"
}