arch-pkgs/bitwig-studio/PKGBUILD

# Maintainer: George Rawlinson <grawlinson@archlinux.org>
# Contributor: Aleksej Komarov <stylemistake@gmail.com>
# Upstream: Bitwig GmbH <support@bitwig.com>

pkgname=bitwig-studio
pkgver=4.3.8
pkgrel=1
pkgdesc='Digital audio workstation for music production, remixing and live performance'
arch=('x86_64')
url='https://www.bitwig.com'
license=('custom:bitwig')
groups=('pro-audio')
depends=(
  'gtk3'
  'libxkbcommon-x11'
  'xcb-util'
  'xcb-util-wm'
)
optdepends=(
  'alsa-lib: alsa audio backend'
  'ffmpeg: mp3 support'
  'jack: jack audio backend'
  'pipewire: pipewire audio backend'
  'pulseaudio: pulseaudio audio backend'
)
provides=('vst-host' 'vst3-host' 'clap-host')
options=('!strip')
source=("$pkgname-$pkgver.deb::https://downloads.bitwig.com/stable/$pkgver/$pkgname-$pkgver.deb")
b2sums=('f5dc342fae769e7a6d0d4f23cfd815baec47d0c3e4c15c649baecceb01d9c257fd88aecc7b53900571e2023a15826c2a66751482a7b264b29a44d48f6c564f02')

package() {
  bsdtar \
    --extract \
    --file data.tar.xz \
    --directory "$pkgdir"

  # license
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" "$pkgdir/opt/$pkgname/EULA.txt"
}