arch-pkgs/python-pydeps/PKGBUILD

# Maintainer: George Rawlinson <grawlinson@archlinux.org>

pkgname=python-pydeps
_name=${pkgname#python-}
pkgver=1.11.0
pkgrel=1
pkgdesc='Python module dependency graphs'
arch=('any')
url='https://github.com/thebjorn/pydeps'
license=('BSD')
depends=(
  'python'
  'python-yaml'
  'python-stdlib-list'
  'graphviz'
)
makedepends=(
  'git'
  'python-build'
  'python-installer'
  'python-wheel'
  'python-setuptools'
)
checkdepends=('python-pytest')
_commit='793e20a43d1adc7798793b42344a480f94e1d7c1'
source=("$pkgname::git+$url.git#commit=$_commit")
b2sums=('SKIP')

pkgver() {
  cd "$pkgname"

  git describe --tags | sed 's/^v//'
}

build() {
  cd "$pkgname"

  python -m build --wheel --no-isolation
}

check() {
  cd "$pkgname"

  # figure out why package can't find pip
  # (even if it is installed as a dependency)
  pytest --ignore tests/test_package_names.py
}

package() {
  cd "$pkgname"

  python -m installer --destdir="$pkgdir" dist/*.whl

  # documentation
  install -vDm644 -t "$pkgdir/usr/share/doc/$pkgname" README.rst

  # license
  install -vDm644 -t "$pkgdir/usr/share/licenses/$pkgname" LICENSE
}